Maxima で綴る数学の旅

紙と鉛筆の代わりに、数式処理システムMaxima / Macsyma を使って、数学を楽しみましょう

-数学- 補助定理III, ガロア群の計算

補助定理IIIでは、全ての根\(\alpha, \beta, \gamma\ldots\)が補助定理IIで導入したVの有理関数f(V)として表されることを述べています。また証明として実際に有理関数f(V)を構成する方法が述べられています。 

 補助定理IIで導入したVは\(\alpha, \beta, \gamma\)の一次結合で表されています。これを逆転して各根\(\alpha, \beta, \gamma\)をVの有理関数で表そうというのです。\(\alpha\)をVの有理関数で表すのであれば、まずVと\(\alpha\)の式を作ります。根の一次結合で\(\alpha\)だけを固定して、\(\beta, \gamma\)の順列をすべて作り、その積をとります。この式は\(\beta, \gamma\)の対称式になるので、それをそれらの基本対称式で表します。そして\(\beta, \gamma\)の基本対称式を\(\alpha, \beta, \gamma\)の基本対称式と\(\alpha\)で表し、それを代入します。これでVと\(\alpha\)だけの式を得ることができます。

この結果を使うと、Vの最小多項式を満たすのはV1〜V6のどれかがわかりますが、その辺は次回になります。

やってみましょう。

Vを主変数として整理するため、その宣言をしておきます。

(%i14) ratvars(V);
$$ \tag{%o14} \left[ V \right] $$

\(\alpha\)を固定して\(\beta, \gamma\)の順列をpermutations()コマンドで作り出し、一次結合に代入し積を取ります。
(%i15) apply("*",map(lambda([perm],V-apply(phi,[alpha,perm[1],perm[2]])),listify(permutations([beta,gamma]))));
$$ \tag{%o15} \left(-3\,\gamma-2\,\beta-\alpha+V\right)\,\left(-2\,\gamma-3\,\beta-\alpha+V\right) $$

これを\(\beta, \gamma\)の基本対称式で表します。
(%i16) tcontract(%,[beta,gamma]);
$$ \tag{%o16} 13\,\beta\,\gamma+6\,\beta^2+\left(5\,\alpha-5\,V\right)\,\beta+\alpha^2-2\,V\,\alpha+V^2 $$
(%i17) p5:elem([2],%,[beta,gamma]);
$$ \tag{%o17} \mathrm{e2}+\mathrm{e1}\,\left(6\,\mathrm{e1}+5\,\alpha-5\,V\right)+\alpha^2-2\,V\,\alpha+V^2 $$

次に\(\beta, \gamma\)の基本対称式を\(\alpha, \beta, \gamma\)の基本対称式(p1の係数)と\(\alpha\)で表します。 

%i18でこの記事の内容を1行で実行し結果をSymACondという変数に格納します。

(%i18) (block([temP],temP:rat(elem([2],tcontract(rat((x-alpha)*(x-beta)*(x-gamma)),[beta,gamma]),[beta,gamma])-p1),
[SymACond]:solve([coeff(temP,x,2)=0,coeff(temP,x,1)=0],[e1,e2])));
$$ \tag{%o18} \left[ \left[ \mathrm{e1}=-\alpha , \mathrm{e2}=\alpha^2-3 \right] \right] $$
%o17の式にこれらをe1, e2として代入することでVと\(\alpha\)の方程式を得ます。
(%i19) p6:rat(p5),SymACond;

$$ \tag{%o19} V^2+3\,\alpha\,V+3\,\alpha^2-3 $$

\(\alpha\)はp1を満たすこと、Vはその最小多項式を満たすこと、Vと\(\alpha\)は%o19を満たすこと、から\(\alpha\)の次数を1次まで下げることができます。この計算、元々はgcdex()やremainder()を使っていたのですが、グレブナー基底で計算してみました。
(%i20) load(grobner)$
(%i21) gb:poly_buchberger([subst(alpha,x,p1),first(p4),p6],[alpha,V]);
$$ \tag{%o21} \left[ \alpha^3-3\,\alpha-1 , V^3-9\,V-9 , 3\,\alpha^2+3\,V\,\alpha+V^2-3 , V^2\,\alpha-3\,\alpha+3\,V+3 , -2\,V\,\alpha-3\,\alpha-V^2-V , -3\,\alpha+V^2-3\,V-6 \right] $$

6番目の式がいい感じですね。これを\(\alpha\)について解きます。
(%i22) solve(%[6],alpha);
$$ \tag{%o22} \left[ \alpha=\frac{V^2-3\,V-6}{3} \right] $$

あとで使うために、Vの関数としても定義しておきます。
(%i23) define(alphaV(V),rhs(%[1]));
$$ \tag{%o23} \mathrm{alphaV}\left(V\right):=\frac{V^2-3\,V-6}{3} $$
(%i24) sol1:alpha=alphaV(V);
$$ \tag{%o24} \alpha=\frac{V^2-3\,V-6}{3} $$

以下、上記と全く同じ計算を\(\beta\)と\(\gamma\)を求めるために2回実行します。下の方を見ていただければ、同じように\(\beta\)とbetaV(V)、\(\gamma\)とgammaV(V)が定義されていることが分かります。

この記事の計算は[1]方程式のガロア群の求め方 – 五次元世界の冒険の中ではルジャンドルの補間公式を使った方法になっています。[2]ガロア論文の古典的証明ではp55に上記の計算が載っています。ただしグレブナー基底ではなく除算や互除法で処理しています。

ここまでで[1]の(6)式の直前までの計算が終わりました。


(%i25) apply("*",map(lambda([perm],V-apply(phi,[perm[1],beta,perm[2]])),listify(permutations([alpha,gamma]))));
$$ \tag{%o25} \left(-3\,\gamma-2\,\beta-\alpha+V\right)\,\left(-\gamma-2\,\beta-3\,\alpha+V\right) $$
(%i26) tcontract(%,[alpha,gamma]);
$$ \tag{%o26} 10\,\alpha\,\gamma+4\,\beta^2+\alpha\,\left(8\,\beta-4\,V\right)-4\,V\,\beta+3\,\alpha^2+V^2 $$
(%i27) p7:elem([2],%,[alpha,gamma]);
$$ \tag{%o27} 4\,\mathrm{e2}+\mathrm{e1}\,\left(3\,\mathrm{e1}+8\,\beta-4\,V\right)+4\,\beta^2-4\,V\,\beta+V^2 $$

(%i28) SymBCond:subst(beta,alpha,SymACond);
$$ \tag{%o28} \left[ \mathrm{e1}=-\beta , \mathrm{e2}=\beta^2-3 \right] $$

(%i29) p8:rat(p7),SymBCond;
$$ \tag{%o29} V^2+3\,\beta^2-12 $$
(%i30) gb:poly_buchberger([subst(beta,x,p1),first(p4),p8],[beta,V]);
$$ \tag{%o30} \left[ \beta^3-3\,\beta-1 , V^3-9\,V-9 , 3\,\beta^2+V^2-12 , -V^2\,\beta+3\,\beta-3 , 2\,V\,\beta+3\,\beta+V , 3\,\beta+2\,V^2-3\,V-12 \right] $$
(%i31) solve(%[6],beta);
$$ \tag{%o31} \left[ \beta=-\frac{2\,V^2-3\,V-12}{3} \right] $$
(%i32) define(betaV(V),rhs(%[1]));
$$ \tag{%o32} \mathrm{betaV}\left(V\right):=-\frac{2\,V^2-3\,V-12}{3} $$
(%i33) sol2:beta=betaV(V);
$$ \tag{%o33} \beta=-\frac{2\,V^2-3\,V-12}{3} $$
(%i34) apply("*",map(lambda([perm],V-apply(phi,[perm[1],perm[2],gamma])),listify(permutations([alpha,beta]))));
$$ \tag{%o34} \left(-3\,\gamma-2\,\beta-\alpha+V\right)\,\left(-3\,\gamma-\beta-2\,\alpha+V\right) $$
(%i35) tcontract(%,[alpha,beta]);
$$ \tag{%o35} 9\,\gamma^2+\alpha\,\left(9\,\gamma-3\,V\right)-6\,V\,\gamma+5\,\alpha\,\beta+2\,\alpha^2+V^2 $$
(%i36) p9:elem([2],%,[alpha,beta]);
$$ \tag{%o36} 9\,\gamma^2+\mathrm{e1}\,\left(9\,\gamma+2\,\mathrm{e1}-3\,V\right)-6\,V\,\gamma+\mathrm{e2}+V^2 $$
(%i37) SymGCond:subst(gamma,alpha,SymACond);
$$ \tag{%o37} \left[ \mathrm{e1}=-\gamma , \mathrm{e2}=\gamma^2-3 \right] $$
(%i38) p10:rat(p9),SymGCond;
$$ \tag{%o38} V^2-3\,\gamma\,V+3\,\gamma^2-3 $$
(%i39) gb:poly_buchberger([subst(gamma,x,p1),first(p4),p10],[gamma,V]);
$$ \tag{%o39} \left[ \gamma^3-3\,\gamma-1 , V^3-9\,V-9 , 3\,\gamma^2-3\,V\,\gamma+V^2-3 , V^2\,\gamma-3\,\gamma-3\,V-6 , -2\,V\,\gamma-3\,\gamma+V^2+2\,V , -3\,\gamma+V^2-6 \right] $$
(%i40) solve(%[6],gamma);
$$ \tag{%o40} \left[ \gamma=\frac{V^2-6}{3} \right] $$
(%i41) define(gammaV(V),rhs(%[1]));
$$ \tag{%o41} \mathrm{gammaV}\left(V\right):=\frac{V^2-6}{3} $$
(%i42) sol3:gamma=gammaV(V);
$$ \tag{%o42} \gamma=\frac{V^2-6}{3} $$

This is a test.
天気