Maxima で綴る数学の旅

紙と鉛筆の代わりに、数式処理システムMaxima / Macsyma を使って、数学を楽しみましょう

-数学- リプシッツ公式を導く

f:id:jurupapa:20141024185033j:plain

にほんブログ村 科学ブログ 数学へ
にほんブログ村

リプシッツ公式(%o1)はオイラーのコタンジェント公式から導くことができます。

(%i1) lip:sum((z-n)^(-k),n,-inf,inf)=(-2*%pi*%i)^k/(k-1)!*sum(n^(k-1)*q^n,n,1,inf);
$$ \tag{%o1} \sum_{n=-\infty }^{\infty }{\frac{1}{\left(z-n\right)^{k}}}=\frac{\left(-i\right)^{k}\,2^{k}\,\pi^{k}\,\sum_{n=1}^{\infty }{n^{k-1}\,q^{n}}}{\left(k-1\right)!} $$

オイラーのコタンジェント公式は(%o2)です。
(%i2) EC:%pi*cot(%pi*z)=sum(1/(z-n),n,minf,inf);
$$ \tag{%o2} \pi\,\cot \left(\pi\,z\right)=\sum_{n= -\infty }^{\infty }{\frac{1}{z-n}} $$

この左辺を変形します。まずcot()を指数関数で表します。
(%i3) lhs(%);
$$ \tag{%o3} \pi\,\cot \left(\pi\,z\right) $$
(%i4) %,exponentialize:true;
$$ \tag{%o4} \frac{i\,\pi\,\left(e^{i\,\pi\,z}+e^ {- i\,\pi\,z }\right)}{e^{i\,\pi\,z}-e^ {- i\,\pi\,z }} $$

これを整理します。
(%i5) %,ratsimp;
$$ \tag{%o5} \frac{i\,\pi\,e^{2\,i\,\pi\,z}+i\,\pi}{e^{2\,i\,\pi\,z}-1} $$

\( q=e^{2\,i\,\pi\,z} \) としてこの式をqで表します。
(%i6) %,exp(2*%pi*%i*z)=q;
$$ \tag{%o6} \frac{i\,\pi\,q+i\,\pi}{q-1} $$

この式をqの冪級数で表すためにpowerseries()という関数を使います。
(%i7) niceindices(powerseries(%,q,0)),niceindicespref:[n];
$$ \tag{%o7} i\,\pi-2\,i\,\pi\,\sum_{n=0}^{\infty }{q^{n}} $$

最初のコタンジェント公式の右辺と合わせると(%o8)が成り立つことがわかります。
(%i8) d0:%=rhs(EC);
$$ \tag{%o8} i\,\pi-2\,i\,\pi\,\sum_{n=0}^{\infty }{q^{n}}=\sum_{n= -\infty }^{\infty }{\frac{1}{z-n}} $$

左辺はqの式、右辺はzの式です。この両辺をzで微分していきます。qはzに依存していて、関係式(%o10)で結ばれています。
(%i9) depends(q,z)$
(%i10) C:q=exp(2*%pi*%i*z);
$$ \tag{%o10} q=e^{2\,i\,\pi\,z} $$

従って合成関数の微分の公式(%o11)を使うことができます。
(%i11) diff(f(q),q)*diff(q,z)=diff(g(z),z);
$$ \tag{%o11} \frac{d}{d\,z}\,q\,\left(\frac{d}{d\,q}\,f\left(q\right)\right)=\frac{d}{d\,z}\,g\left(z\right) $$

qのzでの微分が必要ですから計算しておきます。
(%i12) diff(exp(2*%pi*%i*z),z);
$$ \tag{%o12} 2\,i\,\pi\,e^{2\,i\,\pi\,z} $$

この結果をqで表すと、
(%i13) DC:%,exp(2*%pi*%i*z)=q;

となります。
$$ \tag{%o13} 2\,i\,\pi\,q $$

では(%o8)で求めた式(%o14)を合成関数の微分を使って計算します。
(%i14) d0;
$$ \tag{%o14} i\,\pi-2\,i\,\pi\,\sum_{n=0}^{\infty }{q^{n}}=\sum_{n= -\infty }^{\infty }{\frac{1}{z-n}} $$
(%i15) intosum(diff(lhs(%),q)*DC)=diff(rhs(%),z);
$$ \tag{%o15} \sum_{n=0}^{\infty }{4\,\pi^2\,n\,q^{n}}=-\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^2}} $$

もう一度微分してみましょう。
(%i16) intosum(diff(lhs(%),q)*DC)=diff(rhs(%),z);
$$ \tag{%o16} \sum_{n=0}^{\infty }{8\,i\,\pi^3\,n^2\,q^{n}}=2\,\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^3}} $$

もう一度。
(%i17) intosum(diff(lhs(%),q)*DC)=diff(rhs(%),z);
$$ \tag{%o17} \sum_{n=0}^{\infty }{\left(-16\,\pi^4\,n^3\,q^{n}\right)}=-6\,\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^4}} $$

さらにもう一度。
(%i18) intosum(diff(lhs(%),q)*DC)=diff(rhs(%),z);
$$ \tag{%o18} \sum_{n=0}^{\infty }{\left(-32\,i\,\pi^5\,n^4\,q^{n}\right)}=24\,\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^5}} $$

こんな風にどんどん式が生まれてきます。これらは全てリプシッツの公式でk=1,2,3,4,5,6,,,などと置いた式と一致します。
(%i19) intosum(diff(lhs(%),q)*DC)=diff(rhs(%),z);
$$ \tag{%o19} \sum_{n=0}^{\infty }{64\,\pi^6\,n^5\,q^{n}}=-120\,\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^6}} $$

この式をちょっと見やすく変形してみます。
(%i20) factor(%)/(-120);
$$ \tag{%o20} -\frac{8\,\pi^6\,\sum_{n=0}^{\infty }{n^5\,q^{n}}}{15}=\sum_{n= -\infty }^{\infty }{\frac{1}{\left(z-n\right)^6}} $$

リプシッツの公式でk=6と置くと、
(%i21) lip,k:6;
$$ \tag{%o21} \sum_{n=-\infty }^{\infty }{\frac{1}{\left(z-n\right)^6}}=-\frac{8\,\pi^6\,\sum_{n=1}^{\infty }{n^5\,q^{n}}}{15} $$

ちゃんと一致しました。

ここまでくれば帰納法で証明するのも自明にできることでしょう。

This is a test.
天気