Maxima で綴る数学の旅

紙と鉛筆の代わりに、数式処理システムMaxima / Macsyma を使って、数学を楽しみましょう

-数学- ワイエルシュトラスのペー関数のローラン展開

ワイエルシュトラスのペー関数をローラン展開してみます。ローラン展開といっても、\(\frac{1}{z^2}\)の項はそのまま、総和の部分をべき級数に展開することになります。ここでも以下の記事で定義したペー関数関連の道具は全て読み込み済みとします。

いきなりですが、この有理式のべき級数展開をしてみます。

(%i1) F1:1/(1-x)^2;
$$ \tag{%o1} \frac{1}{\left(1-x\right)^2} $$

powerseries()とniceindices()というコマンドを使います。niceindices()を外したり、つけたりすると効果がよくわかるのでやってみてください。
(%i2) F2:F1=niceindices(powerseries(F1,x,0));
$$ \tag{%o2} \frac{1}{\left(1-x\right)^2}=\sum_{i=0}^{\infty }{\left(i+1\right)\,x^{i}} $$

この結果に\( x=\frac{z}{l} \)を代入します。
(%i3) F3:F2,x:z/l;
$$ \tag{%o3} \frac{1}{\left(1-\frac{z}{l}\right)^2}=\sum_{i=0}^{\infty }{\frac{\left(i+1\right)\,z^{i}}{l^{i}}} $$

sum()の中のi=0の部分をsum()の外に出すことにより、sum()をi=1から始めるようにします。
(%i4) lhs(F3)=modify_part(rhs(F3),lambda([exp],1),3)+ev(part(rhs(F3),1),eval,i:0);
$$ \tag{%o4} \frac{1}{\left(1-\frac{z}{l}\right)^2}=\sum_{i=1}^{\infty }{\frac{\left(i+1\right)\,z^{i}}{l^{i}}}+1 $$

外に出された1を両辺から引きます。
(%i5) %-1;
$$ \tag{%o5} \frac{1}{\left(1-\frac{z}{l}\right)^2}-1=\sum_{i=1}^{\infty }{\frac{\left(i+1\right)\,z^{i}}{l^{i}}} $$

両辺を\( l^{2} \)で割ります。
(%i6) F4:%/l^2;
$$ \tag{%o6} \frac{\frac{1}{\left(1-\frac{z}{l}\right)^2}-1}{l^2}=\frac{\sum_{i=1}^{\infty }{\frac{\left(i+1\right)\,z^{i}}{l^{i}}}}{l^2} $$

実は左辺は\(\frac{1}{\left(z-l\right)^2}-\frac{1}{l^2}\)と等しいことが(%i7), (%i8)から分かります。

(%i7) lhs(%)-(1/(z-l)^2-1/l^2);

$$ \tag{%o7} \frac{\frac{1}{\left(1-\frac{z}{l}\right)^2}-1}{l^2}-\frac{1}{\left(z-l\right)^2}+\frac{1}{l^2} $$
(%i8) %,ratsimp;
$$ \tag{%o8} 0 $$

という訳で以下が成り立ちます。
(%i9) 1/(z-l)^2-1/l^2=intosum(rhs(F4));
$$ \tag{%o9} \frac{1}{\left(z-l\right)^2}-\frac{1}{l^2}=\sum_{i=1}^{\infty }{\left(i+1\right)\,l^{-i-2}\,z^{i}} $$

この\( l \)は格子点を表していたのです。具体的な格子の定義式を代入してみます。
(%i10) %,l:m*w1+n*w2;
$$ \tag{%o10} \frac{1}{\left(z-n\,w_{2}-m\,w_{1}\right)^2}-\frac{1}{\left(n\,w_{2}+m\,w_{1}\right)^2}=\sum_{i=1}^{\infty }{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}} $$

そして両辺を(0,0)を除く格子に渡って足します。
(%i11) clatsumd(lhs(%),n,m)=clatsumd(rhs(%),n,m);
$$ \tag{%o11} \sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\frac{1}{\left(z-n\,w_{2}-m\,w_{1}\right)^2}-\frac{1}{\left(n\,w_{2}+m\,w_{1}\right)^2}}=\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\sum_{i=1}^{\infty }{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}}} $$

両辺に\( \frac{1}{z^2} \)を足します。
(%i12) %+1/z^2;
$$ \tag{%o12} \sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\frac{1}{\left(z-n\,w_{2}-m\,w_{1}\right)^2}-\frac{1}{\left(n\,w_{2}+m\,w_{1}\right)^2}}+\frac{1}{z^2}=\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\sum_{i=1}^{\infty }{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}}}+\frac{1}{z^2} $$

左辺はワイエルシュトラスのペー関数の定義そのものです。
(%i13) 'wp(z,w1,w2)=rhs(%);
$$ \tag{%o13} \wp\left(z , w_{1} , w_{2}\right)=\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\sum_{i=1}^{\infty }{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}}}+\frac{1}{z^2} $$

右辺をさらに変形したいのですが、簡単のために両辺から\( \frac{1}{z^2} \)を引いておきます。
(%i14) %-1/z^2;
$$ \tag{%o14} \wp\left(z , w_{1} , w_{2}\right)-\frac{1}{z^2}=\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\sum_{i=1}^{\infty }{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}}} $$

右辺は絶対収束するので、総和の順番を入れ替えることができます。
(%i15) F5:lhs(%)=sum(clatsumd(part(rhs(%),1,1),n,m),i,1,inf);
$$ \tag{%o15} \wp\left(z , w_{1} , w_{2}\right)-\frac{1}{z^2}=\sum_{i=1}^{\infty }{\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\left(i+1\right)\,\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}\,z^{i}}} $$

m, nに関係ない式は内側の総和からくくり出すことができます。
(%i16) lhs(F5)=sum((i+1)*z^i*clatsumd((m*w1+n*w2)^(-i-2),n,m),i,1,inf);
$$ \tag{%o16} \wp\left(z , w_{1} , w_{2}\right)-\frac{1}{z^2}=\sum_{i=1}^{\infty }{\left(i+1\right)\,\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}}\,z^{i}} $$

さらに式変形するために、総和の内側の部分を取り出します。
(%i17) F6:part(%,2,1);
$$ \tag{%o17} \left(i+1\right)\,\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}}\,z^{i} $$

\(z^i\)の係数を取り出してみます。
(%i18) coeff(F6,z,i);
$$ \tag{%o18} \left(i+1\right)\,\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\left(n\,w_{2}+m\,w_{1}\right)^{-i-2}} $$

この総和の部分に\(G_{k}(w_{1},w_{2})\)と名前をつけます。
(%i19) G[k](w1,w2)=subst(-k,-i-2,part(%,2));
$$ \tag{%o19} G_{k}(w_{1},w_{2})=\sum_{\left(n,m\right) \in Z^2-\left(0,0\right)}{\frac{1}{\left(n\,w_{2}+m\,w_{1}\right)^{k}}} $$

従ってペー関数は以下のようにローラン展開されます。
(%i20) 'wp(z,w1,w2)=1/z^2+sum((i+1)*z^i*G[i+2](w1,w2),i,1,inf);
$$ \tag{%o20} \wp\left(z , w_{1} , w_{2}\right)=\sum_{i=1}^{\infty }{\left(i+1\right)\,G_{i+2}(w_{1},w_{2})\,z^{i}}+\frac{1}{z^2} $$

\( G_{n}(w_1,w_2)\)はnが奇数の時0になります。従って
(%i21) G[2*k+1](w1,w2)=0;
$$ \tag{%o21} G_{2\,k+1}(w_{1},w_{2})=0 $$

まとめると以下の式を得ます。
(%i22) 'wp(z,w1,w2)=1/z^2+sum((2*k+1)*z^(2*k)*G[2*k+2](w1,w2),k,1,inf);
$$ \tag{%o22} \wp\left(z , w_{1} , w_{2}\right)=\sum_{k=1}^{\infty }{\left(2\,k+1\right)\,G_{2\,k+2}(w_{1},w_{2})\,z^{2\,k}}+\frac{1}{z^2} $$

今回も引き続き以下の本を参考にしました。

 

楕円曲線と保型形式

楕円曲線と保型形式

 

 

This is a test.
天気